安川MOTOMAN机器人机器人简介
1、 硬件构成：安川MOTOMAN机器人都是由机器人本体，控制柜两部分构成。
机器人本体上装有伺服马达，传动机构及减速机构等机械装置。这几种型号的机器人都是有六个轴关节，由六台伺服马达和六套传动机构组成。六个轴的名称分别为S、L、U、R、B、T轴，其中S轴控制整个本体的来回旋转、L轴控制机器人下臂的前后摆动、U轴控制机器人上臂上下摆动、R轴控制上臂的来回旋转、B轴控制机器人手腕的上下摆动、T轴控制手腕的来回旋转。六个马达共同运动可以使机器人运行到其工作范围内的任意的一个空间位置。
控制柜内装有全部控制装置、再现操作盒及示教盘。控制装置包括主计算机（CPU单元），伺服马达驱动器，各种外部信号输入输出板，电源装置等。此系列机器人电源的额定输入为AC220V 50/60HZ三相电源，在国内使用时必须配备电源变压器。再现操作盒上装有各种操作按纽、指示灯及通讯口等装置。示教盘上有液晶显示器和各种操作按纽，主要用于编写程序、操作机器人及观察其工作状况等。
2、 机器人工作方式：机器人的工作方式为示教再现型，即由操作者操作机器人完成一遍所有的预定动作，机器人记录下所走过各个位置点的坐标随后自动运行中按照示教的位置、速度完成所有动作。
机器人运动时的坐标系统有五个分别为：关节坐标系、直角坐标 系、圆柱坐标系、工具坐标系和用户坐标系。机器人在关节坐标系中运动方式为各轴单独运动互不影响；在直角坐标系中机器人以本体轴的X、Y、Z三个方向平行移动；在圆柱坐标系中机器人以本体轴Z轴为中心回旋、直角或平行移动；在工具坐标系中机器人以工具尖端点的X、Y、Z轴平行移动；在用户坐标系中由用户在机器人工作的范围之内任意设定不同角度的X、Y、Z轴，机器人可延所设的各轴平行移动。
二．安川MOTOMAN机器人的操作和程序的编写
1、 再现操作盒操作键说明：见P2-3
2、 示教盘操作键说明：见P2-6
3、 程序结构说明：机器人的程序语言为安川公司自己开发的专 用语言（INFORM II），其指令主要分为移动指令、输入输出指令、控制指令和平移指令、运算指令等。 移动指令主要有MOVJ（关节移动），MOVL（直线移动），MOVC（圆弧移动）等。其功能是控制机器人以移动命令规定的方式和速度运行到命令指定的位置。 输入输出指令主要有DOUT（开关量输出的ON或OFF），DIN（将外部开关量输入信号读入），WAIT（等待外部执行条件满足），AOUT（模拟信号输出）等。控制指令主要有JUMP（转移到其它程序步），CALL（调出指定的程序），END（程序结束），TIMER（延时规定的时间），IF（条件判断）等。 运算指令主要有ADD（数据加），SUB（数据减），MUL（数据乘），DIV（除），AND（数据与），OR（数据或）等。
4、编写机器人程序的步骤：大致确定工作所需的位置，打开机器人伺服电源、按下ENABLE键。再用各轴移动键将机器人移动到第一点，按下MOTION TYPE键选择运动方式、按下PLAY SPD键选择运动速度，按下ENTER键确认，第一步程序即编辑完成。用各轴移动键将机器人移动到第二点，用同样的方法确定运动方式和速度完成第二步程序。以此类推完成其它各步骤。最后一步位置要和第一步位置重合可采用如下方式，调出已编辑好的程序，将光标移动到第一步，按下FWD键机器人向设定的第一步的位置移动，到达位置后将光标移动到最后一步，按下MODIFY键再按下ENTER键，最后一步的位置就和第一步重合。
5、程序的检查：按下DISP键再按下F1（JOB）键，将光标移动到第一步，按下FWD键机器人按照编制好的轨迹运动。
6、程序举例说明：排气投入机器人程序
主程序（MASTER JOB）说明：
NOP （空操作）
CLEAR STACK（堆栈清零）
DIN B000 IN#(21)（21#输入送到变量B000）
DIN B001 IN#(22)（22#输入送到变量B001）
DIN B002 IN#(23)（23#输入送到变量B002）
AND B000 B001 （B000与B001）
AND B000 B002 （B000与B001）
JUMP *1 IF IN#(8)=OFF （如条件满足跳转到*1步）
JUMP *1 IF IN#(3)=ON （如条件满足跳转到*1步）
DOUT OT#(1) OFF （关闭输出1#）
DOUT OT#(2) OFF （关闭输出2#）
CALL JOB:QF IF B000=1 （如条件满足调子程序QF）
*1
MOVJ C0000 VJ=70.00 （移动到工作原点位置）
END
子程序QF说明：
NOP （空操作）
MOVJ C0000 VJ=50.00 （移动到位置C000）
JUMP *10 IF IN#(29)=OFF（如条件满足跳转到*10步）
MOVJ C0001 VJ=50.00 （移动到位置C001）
MOVJ C0002 VJ=50.00 （移动到位置C002）
MOVL C0003 V=200.0 （移动到位置C003）
DOUT OT#(1) ON （输出1#ON）
TIMER T=2.00 （延时2秒）
JUMP *11 IF IN#(3)=ON （如条件满足跳转到*11步）
DOUT OT#(9) ON （输出9#ON）
PAUSE （暂停）
*11 DOUT OT#(9) OFF （输出9#OFF）
DOUT OT#(21) ON （输出21#ON）
WAIT IN#(30)=ON （等待输入30#ON）
DOUT OT#(21) OFF （输出21#OFF）
MOVL C0004 V=300.0 （移动到位置C004）
MOVL C0005 V=800.0 （移动到位置C005）
MOVL C0006 V=800.0 （移动到位置C006）
MOVJ C0007 VJ=50.00 （移动到位置C007）
JUMP *12 IF IN#(3)=OFF （如条件满足跳转到*12步）
MOVJ C0008 VJ=50.00 （移动到位置C008）
MOVJ C0009 VJ=50.00 （移动到位置C009）
MOVJ C0010 VJ=50.00 （移动到位置C0010）
MOVJ C0011 VJ=50.00 （移动到位置C0011）
MOVJ C0012 VJ=50.00 （移动到位置C0012）
MOVJ C0013 VJ=50.00 （移动到位置C0013）
MOVJ C0014 VJ=50.00 （移动到位置C0014）
WAIT IN#(31)=OFF （等待输入31#OFF）
WAIT IN#(31)=ON （等待输入31#ON）
MOVL C0015 V=1100.0 （移动到位置C0015）
MOVL C0016 V=200.0 （移动到位置C0016）
DOUT OT#(1) OFF （输出1#OFF）
DOUT OT#(2) ON （输出2#ON）
TIMER T=0.50 （延时0.5秒）
MOVL C0017 V=50.0 （移动到位置C0017）
MOVL C0018 V=1500.0 （移动到位置C0018）
MOVJ C0019 VJ=50.00 （移动到位置C0019）
DOUT OT#(2) OFF （输出2#OFF）
MOVJ C0020 VJ=50.00 （移动到位置C0020）
MOVJ C0021 VJ=50.00 （移动到位置C0021）
MOVJ C0022 VJ=50.00 （移动到位置C0022）
*12
MOVJ C0023 VJ=50.00 （移动到位置C0023）
*10
RET （返回）
END
